Tắt cảnh báo khi gửi mail không có tiêu đề trong Outlook 2010

 

Trong bài hướng dẫn dưới đây, chúng tôi sẽ giới thiệu các bạn cách tắt bảng thông báo “Do you want to send this message without a subject” của Microsoft Outlook 2010.

Xem thêm :

• Gửi – nhận email tự động trong Outlook 2010
• Thêm tài khoản Gmail vào Outlook 2010 với POP
• Thêm tài khoản Gmail vào Outlook 2010 với IMAP
• Thêm Hotmail & Live Email vào Outlook 2010
• Mẹo hay sử dụng Microsoft Outlook 2010
• 10 cách để quản lý Inbox trong Outlook 2010
• Tạo và quản lý Quick Steps trong Outlook 2010
• Làm sạch thư mục và email trên Outlook 2010
• Vô hiệu hóa Outlook Social Connector trong Office 2010
• Tìm kiếm email dễ dàng trong Outlook
• Nhắc nhở đính kèm file trong Microsoft Outlook
• Các bước cơ bản để sao lưu dữ liệu Outlook
• Mẹo copy/paste trong Microsoft Outlook

Trước tiên, mở chương trình Outlook, nhấn Alt + F11 để mở cửa sổ Microsoft Visual Basic:

Sau đó, kích đúp vào phần ThisOutlookSession như hình dưới:

Và điền đoạn mã sau đây:

Option Explicit
'=========================================================================
' Prevents Outlook® 2010 to display a no-subject warning message
' (c) Peter Marchert - http://www.outlook-stuff.com
' 2010-07-15 Version 1.0.0
' 2010-07-19 Version 1.0.1
'=========================================================================
Private WithEvents colInspectors As Outlook.Inspectors
Private Sub Application_Startup()

'---------------------------------------------------------------------
' Set a reference to all forms
'---------------------------------------------------------------------
Set colInspectors = Outlook.Inspectors

End Sub
Private Sub colInspectors_NewInspector(ByVal Inspector As Inspector)

'---------------------------------------------------------------------
' This code is running if a form (e. g. an e-mail) will be opened
'---------------------------------------------------------------------
Dim objItem As Object
'---------------------------------------------------------------------
' Skip errors
'---------------------------------------------------------------------
On Error GoTo ExitProc
'---------------------------------------------------------------------
' Set a reference to the open item
'---------------------------------------------------------------------
Set objItem = Inspector.CurrentItem
'---------------------------------------------------------------------
' A new item does not have a received time
'---------------------------------------------------------------------
If Year(objItem.ReceivedTime) = 4501 Then

'-----------------------------------------------------------------
' Check if the subject is empty if an e-mail was created by a
' template with predefined subject.
'-----------------------------------------------------------------
If objItem.Subject = "" Then objItem.Subject = " "

End If

ExitProc:

'---------------------------------------------------------------------
' Delete the reference to the form and to the item
'---------------------------------------------------------------------
Set objItem = Nothing
Set Inspector = Nothing

End Sub
Private Sub Application_ItemSend(ByVal Item As Object, Cancel As Boolean)

On Error Resume Next
'---------------------------------------------------------------------
' If the blank still exists it will now be removed (Outlook®
' will this not recognize)
'---------------------------------------------------------------------
Item.Subject = Trim(Item.Subject)

End Sub
Private Sub Application_Quit()

'---------------------------------------------------------------------
' Delete the reference to the forms
'---------------------------------------------------------------------
Set colInspectors = Nothing

End Sub

Lưu Session, khởi động lại Outlook và từ lần sau trở đi, nếu bạn gửi email không có phần tiêu đề – Subject thì chương trình sẽ không hiển thị thông báo như trước nữa.

Lưu ý 1 điều rằng chúng ta phải kích hoạt chế độ hoạt động của Macro trong phần Trust Center của Outlook.

Chúc các bạn thành công!

QTM (nguồn Spiceworks)